Future in Hands club

Full Version: Convert currency number to words
You're currently viewing a stripped down version of our content. View the full version with proper formatting.
Looking for a vba Function to convert fi4 example 4267.20 should be four thousands two hundred and sixty seven rupees and twenty paise.
I have created a Function NUMBERTOWORD

Please find the attached file that shows the work in action.

Code:
Function NUMBERTOWORD(ByVal MyNumber)

Dim Rupees As String
Dim Paise As String
Dim Temp As String

Dim DecimalPlace As Integer
Dim Count As Integer
ReDim Place(9) As String

Place(2) = " Thousand "
Place(3) = " Lakh "
Place(4) = " Crore "
Place(5) = " Arab "

MyNumber = Trim(Str(MyNumber))
DecimalPlace = InStr(MyNumber, ".")

If DecimalPlace > 0 Then

   Paise = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2))
   MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))

End If

Count = 1

Do While MyNumber <> ""

   If Count = 1 Then Temp = GetHundreds(Right(MyNumber, 3))
   If Count > 1 Then Temp = GetHundreds(Right(MyNumber, 2))
   If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees

   If Count = 1 And Len(MyNumber) > 3 Then
       MyNumber = Left(MyNumber, Len(MyNumber) - 3)
       Else
       If Count > 1 And Len(MyNumber) > 2 Then
           MyNumber = Left(MyNumber, Len(MyNumber) - 2)
           Else
           MyNumber = ""
       End If
   End If

Count = Count + 1

Loop

Select Case Rupees

Case ""
Rupees = "No Rupees"

Case "One"
Rupees = "One Rupee"

Case Else
Rupees = "Rupees " & Rupees

End Select


Select Case Paise

Case ""
Paise = " Only"

Case "One"
Paise = " and One Paisa Only"

Case Else
Paise = " and " & Paise & " Paise Only"

End Select

NUMBERTOWORD = Rupees & Paise

End Function

Function GetHundreds(ByVal MyNumber)

Dim Result As String

If Val(MyNumber) = 0 Then Exit Function

MyNumber = Right("000" & MyNumber, 3)

If Mid(MyNumber, 1, 1) <> "0" Then
Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
End If

If Mid(MyNumber, 2, 1) <> "0" Then

   Result = Result & GetTens(Mid(MyNumber, 2))
   Else
   Result = Result & GetDigit(Mid(MyNumber, 3))

End If

GetHundreds = Result

End Function

Function GetTens(TensText)

Dim Result As String

Result = ""

If Val(Left(TensText, 1)) = 1 Then

   Select Case Val(TensText)

       Case 10: Result = "Ten"
       Case 11: Result = "Eleven"
       Case 12: Result = "Twelve"
       Case 13: Result = "Thirteen"
       Case 14: Result = "Fourteen"
       Case 15: Result = "Fifteen"
       Case 16: Result = "Sixteen"
       Case 17: Result = "Seventeen"
       Case 18: Result = "Eighteen"
       Case 19: Result = "Nineteen"
       Case Else

   End Select

Else

   Select Case Val(Left(TensText, 1))

       Case 2: Result = "Twenty "
       Case 3: Result = "Thirty "
       Case 4: Result = "Forty "
       Case 5: Result = "Fifty "
       Case 6: Result = "Sixty "
       Case 7: Result = "Seventy "
       Case 8: Result = "Eighty "
       Case 9: Result = "Ninety "
       Case Else

   End Select

   Result = Result & GetDigit(Right(TensText, 1))

End If

GetTens = Result

End Function

Function GetDigit(Digit)

Select Case Val(Digit)

   Case 1: GetDigit = "One"
   Case 2: GetDigit = "Two"
   Case 3: GetDigit = "Three"
   Case 4: GetDigit = "Four"
   Case 5: GetDigit = "Five"
   Case 6: GetDigit = "Six"
   Case 7: GetDigit = "Seven"
   Case 8: GetDigit = "Eight"
   Case 9: GetDigit = "Nine"
   Case Else: GetDigit = ""

End Select

End Function